ton-up blog – とんぶろ

flashなら簡単にあのテレビの砂嵐を再現できるよ！

ってことで10行で作りました
タイムラインに書けば3行！

適当すぎてなんかごめん・・・ｗ

っぽいものを作ってみたｗ

ちょっとショートコーディングしてみようと思ってがんばった
なんかずるいとこもあるかもしれないけど、一応15行
もうちょっと短くなる？

せっかくFP10で３Dの概念が追加されたんだから３Dやってみようってことで

FP10で追加された３Dの機能

・flash.display.DisplayObject クラス
z プロパティやscaleZ
rotationX,rotationY,rotationZなどの各軸の回転角
3次元座標を2次元に変換するlocal3DToGlobal() メソッド　が追加された

・flash.geom.Vector3D クラス
3次元座標を格納するクラス
回転角も入れたりできる
※Vectorクラスとは違います　Vectorクラスはすべてのエレメントが同じデータ型を持つ配列で、Vector３Dクラスは3次元空間のベクトルを表すクラスです

・flash.geom.Matrix3D クラス
回転、拡大、縮小、平行移動などの３Dの変換を行うクラス

・flash.geom.PerspectiveProjection クラス
遠近法に基づく変形を行うクラス

とりあえずくるくる回転するだけの物を作ってみた

package {
import flash.display.Sprite;
import flash.events.Event;

public class Study3d1 extends Sprite {
private const SIZE:int = 100;
private const W:int = stage.stageWidth;
private const H:int = stage.stageHeight;
private var mc:Sprite;
public function Study3d1():void {
mc = new Sprite();
mc.graphics.beginFill(0x0077ff);
mc.graphics.drawRect(-SIZE/2, -SIZE/2, SIZE, SIZE);
mc.graphics.endFill();
mc.x = W / 2;
mc.y = H / 2;
addChild(mc);

addEventListener(Event.ENTER_FRAME, onEnterFrameHandler);
}

private function onEnterFrameHandler(e:Event):void {
mc.rotationX = H / 2 - mouseY;
mc.rotationY = W / 2 - mouseX;
}
}
}

おー回ってる回ってる
次はもちっと複雑な動きをする物を作ってみたいと思います

AS3ではサウンドの波形が簡単にとれるということなのでちょっと作ってみました

色はランダムなので色々試してみるといいかも

※クリックでstart

SoundComputeSpectrum.as

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.geom.ColorTransform;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.utils.ByteArray;

	[SWF(width=512, height=200,backgroundColor=0xffffff)]
    public class SoundComputeSpectrum extends Sprite {
       	[Embed(source="sound.mp3")]
       	private var mySound:Class;
    	private var lineArray:Array = new Array();
        private const HEIGHT:int = 100;
        private const LENGTH:int = 512;
        private const VC:int = 20;

        public function SoundComputeSpectrum() {
        	stage.addEventListener(MouseEvent.CLICK, init);
        }

        private function init(event:MouseEvent):void{
        	stage.removeEventListener(MouseEvent.CLICK, init);
         	var color:uint = Math.random()*0xffffff;
        	for(var i:int = 0; i < LENGTH; i++){
        		var sp:Sprite = new Sprite();
        		sp.x = i;
        		sp.y = HEIGHT;
        		sp.graphics.lineStyle(0,color);
        		sp.graphics.lineTo(0,1);
        		addChild(sp);
        		lineArray.push(sp);
        	}

            var channel:SoundChannel = new mySound().play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, completeHandler);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            SoundMixer.computeSpectrum(bytes, false, 0);
            var rf:Number;
            for (var i:int = 0; i < LENGTH; i++) {
            	rf = bytes.readFloat();
            	lineArray[i].alpha = Math.abs(rf);
            	lineArray[i].scaleY = -rf*HEIGHT;
            }
            var ro:Number = stage.transform.colorTransform.redOffset + Math.random()*VC - VC/2;
            var go:Number = stage.transform.colorTransform.greenOffset + Math.random()*VC - VC/2;
            var bo:Number = stage.transform.colorTransform.blueOffset + Math.random()*VC - VC/2;
            stage.transform.colorTransform = new ColorTransform(1,1,1,1,ro,go,bo,0);
        }

        private function completeHandler(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

自分のやりかたが悪いのでちょっと重いですが、がんばればかなり軽くなるはず！
それにしても簡単に波形がとれていいですねー
あとByteArray便利
こいつがあればなんでも出来そうな気がする！　おおげさですかｗ
今度ByteArrayを使ってごにょごにょやってみようかな

樹木曲線はフラクタルで木を再現したもので、コンピュータアートの分野では有名です
ある程度ランダムな要素を入れるとかなり現実の木に近くなります

※クリックでstart

Line.as

package {
	import flash.display.Sprite;
	import flash.geom.Point;
	public class Line extends Sprite {
		public var startP:Point;
		public var endP:Point;
		public var distance:Number;
		public var angle:Number;
		function Line(startP:Point, endP:Point) {
			this.startP = startP;
			this.endP = endP;
			angle = Math.atan2(endP.y-startP.y, endP.x-startP.x);
			distance = Point.distance(startP, endP);
			graphics.lineStyle(0,0x000000);
			graphics.moveTo(startP.x, startP.y);
			graphics.lineTo(endP.x, endP.y);
			graphics.endFill();
		}
	}
}

TreeCurve.as

package {
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.events.Event;
	import flash.geom.Point;
	public class TreeCurve extends Sprite {
		private var list:Array = [];
		private const W:int = 300;
		private const H:int = 300;
		private const RAD:Number = Math.PI/8;
		private const a:Number = 0.75;
		function TreeCurve() {
			var line:Line=new Line(new Point(W/2, H), new Point(W/2, H*4/5));
			list.push(line);
			stage.addChild(line);
			stage.addEventListener(MouseEvent.CLICK,onClick);
			function onClick(event:MouseEvent):void {
				stage.addEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
				stage.removeEventListener(MouseEvent.CLICK,onClick);
			}
		}
		private function onEnterFrameHandler(event:Event):void {
			var line:Line=list[0];
			list.splice(0, 1);
			if (line.distance <=  {
				stage.removeEventListener(Event.ENTER_FRAME, onEnterFrameHandler);
				return;
			}
			var p:Point = new Point(line.endP.x + line.distance * a * Math.cos(line.angle + RAD), line.endP.y + line.distance * a * Math.sin(line.angle+RAD));
			var newLine:Line = new Line(line.endP, p);
			list.push(newLine);
			stage.addChild(newLine);
			p = new Point(line.endP.x + line.distance * a * Math.cos(line.angle - RAD), line.endP.y + line.distance * a * Math.sin(line.angle - RAD));
			newLine = new Line(line.endP, p);
			list.push(newLine);
			stage.addChild(newLine);
		}
	}
}